Mathematica code to solve a certain degree 10 Diophantine equation in 3 variables under some conditions - Ziqing Xiang

This is the Mathematica code for the joint work with Eiichi Bannai, Etsuko Bannai, Wei-Hsuan Yu and Yan Zhu entitled "Classification of spherical 2-distance {4, 2, 1}-design".

Section 3

Definition of Gegenbauer polynomial (Subscript[Q, n, 4])(ξ).

Q[n_,4,ξ_]:=n(n+6)/24((n^2+6n+8)ξ^4-6(n+2)ξ^2+3);

Definition of F. Eq. (3.4).

F=Factor[Q[n,4,1]+k Q[n,4,y/k]+(v-k-1)Q[n,4,(-y-1)/(v-k-1)]/.v->1/μ(k-x)(k-y)/.k->μ-x y/.n->(μ-x y)(μ-x y-x)(x+1)/μ/(x-y)]

The four factors (Subscript[F, 0]), (Subscript[F, 1]), (Subscript[F, 2]), (Subscript[F, 3]) of F. Eqs. (3.5) - (3.8).

F0=(μ-x-x y) (((μ-y-x y))^2) /(24 (μ^4) (((1+x))^2) (((x-y))^4) (((μ-x y))^2));
F0
F1=(μ^2)+5 μ x+(μ^2) x-μ (x^2)-6 μ y-2 μ x y+(x^2) y-2 μ (x^2) y+(x^3) y+(x^2) (y^2)+(x^3) (y^2) ;
Collect[F1,{μ,y},Factor]
F2=(μ^2)+3 μ x+(μ^2) x-μ (x^2)-4 μ y-2 μ x y+(x^2) y-2 μ (x^2) y+(x^3) y+(x^2) (y^2)+(x^3) (y^2);
Collect[F2,{μ,y},Factor]
F3=3 (μ^3) x+6 (μ^3) (x^2)-6 (μ^2) (x^3)+4 (μ^3) (x^3)-5 (μ^2) (x^4)+(μ^3) (x^4)-(μ^2) (x^5)-(μ^3) y+2 (μ^2) x y-(μ^3) x y+7 (μ^2) (x^2) y-6 (μ^2) (x^3) y+5 μ (x^4) y-10 (μ^2) (x^4) y+7 μ (x^5) y-3 (μ^2) (x^5) y+2 μ (x^6) y-3 (μ^2) (y^2)+μ x (y^2)-8 (μ^2) x (y^2)+2 μ (x^2) (y^2)-3 (μ^2) (x^2) (y^2)-3 μ (x^3) (y^2)+μ (x^4) (y^2)-(x^5) (y^2)+8 μ (x^5) (y^2)-2 (x^6) (y^2)+3 μ (x^6) (y^2)-(x^7) (y^2)-2 μ (y^3)-4 μ x (y^3)+(x^2) (y^3)+μ (x^2) (y^3)+2 (x^3) (y^3)+3 μ (x^3) (y^3)+(x^4) (y^3)-(x^5) (y^3)-2 (x^6) (y^3)-(x^7) (y^3)+(x^2) (y^4)+2 (x^3) (y^4)+(x^4) (y^4);
Collect[F3,{μ,y},Factor]

Verify the factorization.

Simplify[F0 F1 F2 F3-F]

Section 5.2

Alternative definition of n and v. Eqs. (5.1) and (5.2).

n=(x+1)(μ-x y)(μ-x y-x)/(μ(-y+x));
v=n+1-(y n+μ-x y)/x;

Step 1

Assumption on y in Step 1. Eq. (5.3).

yassum=y≤-(2x^3+3x^2+3x+2)||-(2x^3+3x^2-3x-3)≤y≤-1;

The computer proof for Step 1.

Simplify[v>n(n+3)/2||F3>0,x≥1&&μ≥1&&yassum]

Step 2

Definition of a. Eq. (5.4).

usub=μ->-(x+a)y;

Definition of (Subscript[G, 1]).

G1=Factor[(F3/.usub)/y^2];
Collect[G1,{y,x},Factor]

The computer proof for Step 2(a).

Simplify[(G1/.y->0)<0,2≤x&&-x<a]

The computer proof for Step 2(b).

Simplify[(G1/.y->-1)>0,2≤x&&-x<a]

The computer proof for Step 2(c).

Simplify[(G1/.y->-(2x^3+3x^2+3x+2))>0,2≤x&&(-x<a≤-1||3≤a)]

Step 3

Definition of b. Eq. (5.11).

ysub=y->-(2 (x^3)+3 (x^2)+(3/2) (-1+a) a x-(3/2) (((-1+a))^2) a+(1/(4 x))3 (-1+a) a (2-4 a+3 (a^2))-(1/(4 (x^2)))3 (-1+a) (a^2) (3-6 a+4 (a^2))+(1/(8 (x^3)))3 (-1+a) a (5-9 a+16 (a^2)-20 (a^3)+11 (a^4))+(b/(x^4)));

Definition of (Subscript[G, 2]).

G2=Factor[G1/.ysub];
Collect[G2,x,Factor]

The computer proof for Step 3(a).

Simplify[(G2/.b->-3994)>0,90≤x&&-1≤a≤3]

The computer proof for Step 3(b).

Simplify[(G2/.b->64)<0,90≤x&&-1≤a≤3]

Step 4

Definition of (m^2). Eq. (5.12).

mmsub=mm->n-(4x^2+4x-2);

Definition of (Subscript[G, 3]).

G3=Factor[mm/.mmsub/.usub/.ysub];
G3

Definition of ((OverTilde[m])^2). Eq. (5.12).

mmtsub=mmt->(a^2)-(((-1+a) (a^2))/x)+(((-1+a) a (1+(a^2)))/(x^2))-(1/(2 (x^3)))(-1+a) a (1+2 a+2 (a^3))+(1/(4 (x^4)))(-1+a) a (7-a+4 (a^2)+4 (a^4))+(c/(x^5));

Definition of (Subscript[G, 4]).

G4=Factor[mmt/.mmtsub];
Collect[G4,x,Factor]

The computer proof for Step 4(a).

Simplify[G3>(G4/.c->-1620),90≤x&&-1≤a≤3&&-3994≤b≤64]

The computer proof for Step 4(b).

Simplify[G3<(G4/.c->3),90≤x&&-1≤a≤3&&-3994≤b≤64]

The computer proof for Step 4(c).

Simplify[G4<9,90≤x&&-1≤a≤3&&-1620≤c≤3]

Step 5

Definition of (OverTilde[n]). Eq. (5.16).

nt=mmt+(4x^2+4x-2);
Collect[nt/.usub/.ysub/.mmtsub,x,Factor]

Definition of (OverTilde[v]). Eq. (5.16).

vt=nt+1-(y nt+μ-x y)/x;
Collect[vt/.usub/.ysub/.mmtsub,x,Factor]

Definition of (OverTilde[z]). Eq. (5.15).

zt=144mmt-(3vt+(8y+4x^3+6x^2+3)(2x+1)-3/2mmt(mmt-7))^2;

Definition of (Subscript[G, 5]).

G5=Factor[zt/.usub/.ysub/.mmtsub];
Collect[G5,x,Factor]

The computer proof for Step 5(a). We use maximum value as an upper bound when -5≤i≤-2, and use the maximum absolute sum as an upper bound when -20≤i≤-6.

coeff=Table[If[i≥-5,
Maximize[{Abs[Coefficient[G5,x^i]],-1≤a≤3&&-3994≤b≤64&&-1620≤c≤3},{x,a,b,c}][[1]],
FromCoefficientRules[Map[Abs,CoefficientRules[Coefficient[G5,x^i],{x,a,b,c}],{2}],{x,a,b,c}]/.a->3/.b->3994/.c->1620
],{i,-20,-2}]

The computer proof for Step 5(b).

Simplify[Total[coeff x^Range[-20,-2]]<1,x≥120]

Step 6

Definition of (Subscript[G, 6]).

G6=Factor[μ(y-x)(mm-m0^2)/.mmsub];
Collect[G6,μ,Factor]

Definition of (Subscript[F, 4]). Eq. (5.18)

F4=Denominator[Factor[PolynomialExtendedGCD[F3,G6,μ]][[2]]][[1]]/((x^2) (((1+x))^2) (x-y) (y^2) (1+y));
Collect[F4,y,Factor]

Step 7

Definition of (y^((1))), (y^((2))), (y^((3))).

y1=-(2 (x^3)+3 (x^2)+(3/2)m0(m0+1)x+(3/4)m0(m0+1));
y2=-(2 (x^3)+3 (x^2)+(3/2)m0(m0-1)x+(3/4)m0(m0-1));
y3=x;

The computer proof for Step 7(a).

Simplify[(F4/.y->y1)==0,m0==0]

The computer proof for Step 7(b).

Simplify[(F4/.y->y1-1/2)>0,x≥90&&1≤m0≤2]

The computer proof for Step 7(c).

Simplify[(F4/.y->y1+1/2)<0,x≥90&&1≤m0≤2]

The computer proof for Step 7(d).

Simplify[(F4/.y->y2+1/x)<0,x≥90&&m0==0]

The computer proof for Step 7(e).

Simplify[(F4/.y->y2-1/2)<0,x≥90&&1≤m0≤2]

The computer proof for Step 7(f).

Simplify[(F4/.y->y2+1/2)>0,x≥90&&0≤m0≤2]

The computer proof for Step 7(g).

Simplify[(F4/.y->y3-1)>0,x≥1&&0≤m0≤2]

The computer proof for Step 7(h).

Simplify[(F4/.y->y3+1)<0,x≥1&&0≤m0≤2]

Step 8

Speed up Step 8 using multiple kernels.

LaunchKernels[8];

The computer proof for Step 8.

Select[DeleteDuplicates[Flatten[ParallelTable[
If[(μ/.#)>0&&y0≤-1&&y0≠-(2x0^3+3x0^2),{x0,y0,μ/.#},{}]&/@Solve[(F3/.x->x0/.y->y0)==0,μ,Integers]
,{x0,1,120},{y0,-(2x0^3+3x0^2+3x0+2),-(2x0^3+3x0^2-3x0-3)}],2]],Length[#]>0&]